Forum

@echo off




set sourceFile=d:\backupscript\server\kav7.0.0.125de.exe
set backupPath=d:\backupscript\server\ftpDir\
set tmpPath=d:\backupscript\server\tmp\
set gpg=c:\Programme\GnuPG\gpg.exe
set rar=c:\Programme\winrar\rar.exe
set blocksize=1024
set targetUser=Stephan Schuler




echo .
echo .
echo .
echo Clear backup directory.
rmdir /S /Q %backupPath%
rmdir /S /Q %tmpPath%
mkdir %backupPath%
mkdir %tmpPath%




echo .
echo .
echo .
echo Create working copy in tmp path.
copy %sourceFile% %tmpPath%




echo .
echo .
echo .
echo Jump to backup directory.
cd %tmpPath%




echo .
echo .
echo .
echo Process whole backup file.
for %%f IN (*) DO (

  echo .
  echo Encrypt file %%f.
  call "%gpg%" -e -r "%targetUser%" "%%f"

  echo Md5sum file %%f.
  md5sum %%f > %%f.md5

  echo Delete source tmp file %%f.
  del %%f
)




echo .
echo .
echo .
echo Compress and make blocks.
call %rar% a -v%blockSize% -inul backup.rar *




echo .
echo .
echo .
echo Calculate md5sums for blocks.
md5sum *.rar > backup.rar.md5




move *.rar %backupPath%
move *.md5 %backupPath%

@echo off




set workingDir=d:\backupscript\client\downdir\
set gpg=c:\Programme\GnuPG\gpg.exe
set rar=c:\Programme\winrar\rar.exe
set ftpHost=10.214.1.5
set ftpUser=ftpbenutzername
set ftpPass=ftppasswort
set com=comfile
set maxRunner=5




setlocal ENABLEDELAYEDEXPANSION




echo .
echo .
echo .
echo Jump to working directory.
cd %workingDir%




set runnerCount=0
:listCreator
set /a runnerCount=!runnerCount!+1
IF !runnerCount!==%maxRunner% (
  echo .
  echo .
  echo .
  echo !runnerCount! times failed, try again tomorrow.
  goto :EOF
)




echo .
echo .
echo .
echo Create md5-getter
echo OPEN %ftpHost% > %com%
echo USER %ftpUser% %ftpPass% >> %com%
echo GET backup.rar.md5 >> %com%
echo QUIT >> %com%




echo .
echo .
echo .
echo Get backup file list from ftp.
ftp -n -s:%com% > nul
del %com%




echo .
echo .
echo .
echo Process list of md5 values.
for /F "tokens=1,2" %%a in (backup.rar.md5) do @(

  set file=%%b
  set file=!file:~1!
  set md5sum=%%a
  echo .
  echo .
  echo .
  echo Processing !file!

  echo Make shure that !file! exists.
  @dir !file! > nul
  IF ERRORLEVEL 1 (
    echo Not found, created empty file.
    echo "" > !file!
  ) ELSE (
    echo Found, ready to compare.
  )

  @echo %%a %%b> md5.foreign.tmp
  @md5sum -b !file!> md5.local.tmp

  fc md5.foreign.tmp md5.local.tmp > nul
  if ERRORLEVEL 1 (
    echo Different, download from ftp.
    echo OPEN %ftpHost% > %com%
    echo USER %ftpUser% %ftpPass% >> %com%
    echo GET !file! >> %com%
    echo QUIT >> %com%
    ftp -n -s:%com% > nul
    del %com%
    echo File downloaded.
  ) ELSE (
    echo Allready in sync.
  )
  del md5.foreign.tmp
  del md5.local.tmp
  


)




md5sum -c backup.rar.md5 > nul




if ERRORLEVEL 1 (
  echo .
  echo .
  echo .
  echo Some files are out of sync, starting again.
  goto listCreator
)




del backup.rar.md5




echo .
echo .
echo .
echo Uncompress archive file
call %rar% e -o+ -inul backup.part01.rar > nul




echo .
echo .
echo .
echo Decrypt all crypted files.
for %%i IN (*.gpg) DO (

  set file=%%i
  set file=!file:~0,-4!

  echo .
  echo Decrypt !file!.
  call %gpg% -d %%i > !file!

  echo .
  echo Delete encrypted file.
  del %%i

  echo .
  echo Check md5sum of encrypted file.
  md5sum --check --status !file!.md5

  IF ERRORLEVEL 0 (
    echo Decrypted with valid result.
  )

)




echo .
echo .
echo .
echo Done.